ここに挙げる関数は、 Eggplant FunctionalのViewerウィンドウで最後に見つかった画像またはテキスト（OCR）検索に関する追加情報を返します。これらの関数は特に、見つかった画像を必ずしも把握していない状態で、あらゆる形態のコマンドや他の関数を使用するのに便利です。
FoundImageInfo()関数
例：
Click text:"Single Sign-On"
put FoundImageInfo() // 先ほど成功した画像またはOCR検索に関するFoundImageInfoの戻り値を出力します
例：
WaitFor 10, "WelcomeMessage"
log the FoundImageInfo's description // 画像説明の内容をログします
例：
click "SignInButton"
set clickedImage to FoundImageInfo()'s imageName // 一番最近見つかった画像の名前をclickedImageという変数に格納します
例：
WaitFor 10, "WelcomeMessage"
set myImageInfo to the FoundImageInfo // FoundImageInfoからの戻り値をmyImageInfoという変数に格納します
assert that the CaptureLocation of myImageInfo equals the ImageLocation of myImageInfo // 見つかった「WelcomeMessage」画像のCaptureLocationとImageLocationが等しいことを例外付きで表明します
例：
WaitFor 60, "Username","Yes" // 2つの画像（「Username」と「Yes」）の検索を最大60秒間にわたって交互に行います
put the short name of file the foundimageinfo's imagepath into FoundImage // WaitForコマンドによって最初に見つかった画像の名前を格納します
If FoundImage is "Username" then
Click "Username"
else if FoundImage is "Yes"
Click "Yes"
Click (image:"Username",waitFor:10)
End If
例：
この例では、画像検索を実行するたびにFoundImageInfo()を収集するオーバーライドを使用しています。
メインスクリプト：
global ImageUsage // メインスクリプトにおいて、検索された各画像の使用状況を収集するグローバル変数を宣言します
start using "ImageTrackingOverrides" // ここからは組み込みのコマンドではなく、ImageTrackingOverridesスクリプト内のオーバーライドコマンド一式を使用するようEggplantに指示します
DoubleClick "BrowserIcon"
Click "AddressBar"
put imageUsage into file "C:\Users\Carrie\Desktop\myImageUsage.txt" // メインスクリプトの実行の最後に、imageUsageの中身をファイルに書き出します
ImageTrackingOverridesスクリプト：
to Click // オーバーライドコマンドは、オーバーライド対象のコマンドと同じ名前にします
pass message and continue // メッセージ、すなわちハンドラ名（この場合は「Click」）とハンドラに渡されるパラメータ（該当する場合）を渡します
GatherImageInfo // 以下に定義する再利用可能なカスタムコマンドGatherImageInfoを呼び出します
end Click
to DoubleClick
pass message and continue
GatherImageInfo
end DoubleClick
// カスタムコマンドGatherImageInfoを作成します
on GatherImageInfo
global ImageUsage // コマンドにおいてグローバル変数を宣言します
set myImageInfo to FoundImageInfo()
put myImageInfo. ImageName&comma&the short name of file myImageInfo. ImagePath&CRLF after ImageUsage
// 画像参照と実際に見つかった画像の名前を取り、それにキャリッジリターン改行を付けてグローバル変数ImageUsageの末尾に追加します
end GatherImageInfo
パラメータ：なし（一番最後に見つかった画像が参照されます）。
戻り値：画像またはOCRのプロパティリスト。例：
画像検索の場合：
(CaptureDate:"2016-09-09 13:02:53 -0600", CaptureHost:"Windows", CaptureLocation:(305,270), CaptureScreenSize:(1024,768), Description:"", HotSpot:(41,14), ImageLocation:(346,284), ImageName:"WelcomeMessage", ImagePath:"C:/Users/Carrie/Documents/Suites/mySuite.suite/Images/WelcomeMessage.png", ImageRectangle:(305,270,387,298), ImageSize:(82,28), ImageTolerance:"53", Pulsing:"False", Scale:"1", SearchType:"Smooth")
OCR検索の場合：
(CaseSensitive:"No", Contrast:"Off", IgnoreSpaces:"No", ImageLocation:(351,283), ImageRectangle:(319,277,384,290), Language:"English", searchrectangle:(230,242,504,371), text:"TestPlant", TextPlatform:"Generic OCR", validcharacters:"TestPlant")
挙動：1つの画像またはOCR検索に対してはプロパティリストを、複数の参照に対してはプロパティリストのリストを返します。利用可能なデータによっては、画像プロパティやOCRプロパティに挙がっているプロパティに加え、次のプロパティがリストに含まれる可能性があります。
画像検索の場合：
- Description：Suite Editor Infoパネル内の画像説明。
- ImageLocation：ImageLocation()関数を使用して見つかった画像の座標。
- ImageRectangle：ImageRectangle()関数を使用して見つかった画像の矩形座標。
FoundImageLocation()関数
例：
If ImageFound("OKButton") then click the FoundImageLocation // FoundImageLocationによって返される位置をクリックします
例：
WaitFor 30, text:"Sign Out"
set SignOutButtonLocation to FoundImageLocation() // 成功したOCR検索の中心点の位置をSignOutButtonLocationという変数に格納します
ValidateAccountConfiguration // ValidateAccountConfigurationという名前のスクリプトを実行します
Click SignOutButtonLocation // SignOutButtonLocationに格納されている位置をクリックします
例：
Click "SelectNode"
Wait .5 // RemoteWorkIntervalの値によっては、ClickとDragの振る舞いが合わさってDoubleClickのようにならないよう、短い待ち時間が必要です
Drag FoundImageLocation() // SelectNodeのホットスポット位置でドラッグを開始します
Drop "EndNode" // EndNodeのホットスポット位置でドラッグを終了します
パラメータ：なし（一番最後に見つかった画像またはテキスト（OCR）が参照されます）。
戻り値：座標。例：(195,137)
挙動：SUT上で見つかった一番最近の画像またはテキスト（OCR）のホットスポットの画面座標を返します。
FoundImageNumber()関数
例：
WaitFor 10, "WelcomeMessage", "SignOutButton", "CompanyLogo"
If the FoundImageNumber is not 1 then LogWarning "The page loaded but not in the expected order." // SignOutButtonまたはCompanyLogoが最初に見つかった場合は、FoundImageNumberによってそれぞれ2または3が返され、警告メッセージをログする文が発動されます
例：
Click (text:"Single Sign-On"), "SignOut"
log foundImageNumber() // 見つかった要素の順序位置番号をログします
パラメータ：なし（一番最後に見つかった画像またはテキスト（OCR）が参照されます）。
戻り値：コマンドまたは関数のパラメータリスト内における当該画像またはテキスト（OCR）の順序位置を表す1つの数字。例：3
FoundImageName()関数（非推奨）
パラメータ：なし（一番最後に見つかった画像が参照されます）。
戻り値：画像名。
注： FoundImageNameは非推奨です。代わりに、FoundImageInfo()'s imageNameまたはFoundImageInfo()'s imagePathを使用してください。
挙動：一番最後に見つかった画像の名前を返します。
Eggplant.io | Documentation Home | User Forums | Support | Copyright © 2019 Eggplant