再利用コード

CycleWindows // Calls a simple script name as a command

ConnectionScript "Old SUT", "New SUT" // Calls a simple script name with parameters

put CaptureTheScreen("SomePrefix",1) into myScreenCapture

// Calls a script as a function with parameters and puts the result in a variable

Run "/Users/Seiji/Documents/EggPlant Suites/Validation.suite/Scripts/ConnectionScript"

// Calls the Run command to open a script from an unrelated suite

to CaptureTheScreen prefix, count // Starts the handler

set fileName to prefix & "ScreenShot" & count // Puts prefixScreenShotCount into fileName

set tempFile to "/tmp/" & fileName // Puts "/tmp/filename" into tempFile

CaptureScreen tempFile //Captures a screenshot

return fileName // Sets fileName as the function return value

end CaptureTheScreen //Ends the handler

CaptureTheScreen "MacTest", 6 // Calls the CaptureTheScreen handler

Set newFile to the result // Puts the returned value into a variable

CaptureTheScreen "MacTest", 6 // Called as a command; runs the handler

put CaptureTheScreen ("MacTest",6) // Called as a function; returns the value of the handler. Note parentheses.

run Logging's CaptureTheScreen "MacTest", 6 // Calls handler with script name and possessive 's

run Logging. CaptureTheScreen "MacTest", 6 // Calls handler in the form script.handler

run CaptureTheScreen of Logging "MacTest", 6 // Calls handler with handler "of" script

put SuiteInfo().path // Returns the path to suite containing this script

put the folder of me // Returns the full path to the Scripts folder containing this script

set the InitialSuites to (DSD & "myFirstSuite.suite", DSD & "mySecondSuite.suite")

set the FinalSuites to (DSD & "mySuite.suite", DSD & "myOtherSuite.suite")

TypeText ControlKey & AltKey & "x"

TypeText CommandKey & "q"

Set the InitialSuites to ("Windows") // Names the Windows suite as the first suite to check for resources

Quit // Runs the first Quit script found

Click (text: "Open", textStyle: "Button")

Click (text: "Ouvrir", textStyle: "Button")

Click (text: "Abierto", textStyle: "Button")

params EnglishWord// Takes an English word...

set translation to {Hello: "Bonjour",Open: "Ouvrir",Yes: "Oui"} // Sets the translation variable to a property list, in which each English key is assigned a French value

return translation's (EnglishWord) // Returns the French value of the English key that was passed in

Set the InitialSuites to ("French") // Ensures that the "Translate" script comes from the French suite

Click (text: Translate ("Hello")) // Runs the "Translate" script with "Hello" as the EnglishWord parameter. Uses the returned value of "Translate" as the Text value in this property list.

params BaseWord// Takes a word...

return BaseWord// Returns the same word.

//This script makes a note in Evernote on an Android device and then checks that the note was processed and shows up in a web browser on a Windows 7 VM//

//Populate variables (could also be drawn from a data file or database)

Put "Bananas" into MyFruit

Put "Carrots" into MyVeggie

AddItemsFromAndroid MyFruit, MyVeggie --Call script to add items to a grocery list from an Android device

CheckItemsInBrowser MyFruit, MyVeggie --Call script to connect to a Win 7 VM and login to Evernote online to see if the items updated

CheckItemsInDesktopApp MyFruit, MyVeggie --Call script that uses the Evernote desktop application to verify the list items

ClearList MyFruit, MyVeggie --Clear the List for Next Test Run

//This script goes into Evernote on Android and adds items to the grocery list

Params Fruit, Veggie

Log "Entering Items in List via Android"

Connect GalaxyS3 //Connect to the device

Tap "AppMenu" //Navigate to the Evernote app

Tap "Evernote" //Navigate to the list

Tap "NoteIcon"

Tap "GroceryList"//Edit the list and add the items

Tap "EditIcon"

WaitFor 30.0, "Check"

TypeText Fruit, return

TypeText Veggie, return

//Save the list and navigate back to the home page

Tap "Check"

Wait 1

Tap "ElephantIcon"

TypeText HomeKey //Navigates to the home page using the home button on the device

WaitFor 30.0, "ChromeIcon" //Verifies that the home page of the device is displayed

//This script connects to a Win 7 VM and verifies the list items in Evernote through a web browser

Params Fruit, Veggie

Log "Checking the list items in a browser"

Connect Win7Demo //Connect to Win 7 VM

//Navigate to Evernote.com

DoubleClick "GoogleChrome"

WaitFor 30.0, "GoogleMenuLogo"

TypeText "Evernote.com",return

//Log In and make sure grocery list is selected

Click "SignIn"

TypeText "<email address>"

TypeText TabKey

TypeText "<password>"

Click "SignInButton"

Click "GroceryList"

//Find the Date Created and Log it

Put ReadText ("CreatedTLDate","CreatedBRDate") into DateCreated

Log "This List was Created on: " & DateCreated

//Find the Date Last Modified and Log it

Put ReadText ("ModifiedTLDate","ModifiedBRDate") into DateModified

Log "This List was Last Modified on: " & DateModified

//Read the Contents of Grocery List

Put ReadText ("TLList","BRList") into ListContents

Log "The list contained: " & ListContents

//Check to see if Fruit was properly synced

If ListContents contains Fruit

then

log "The list contained " & Fruit

else

logWarning "The item " & Fruit & " was not displayed"

end if

//Check to see if Veggie was properly synced

If ListContents contains Veggie

then

log "The list contained " & Veggie

else

logWarning "The item " & Veggie & " was not displayed"

end if

//Close out of Browser

Click "CloseButton"

//This script connects to a Win 7 VM and verifies the list items in the Evernote desktop application//

Params Fruit, Veggie

//Declares parameters. For an example on passing parameters, please see "Passing Parameters and Calling Functions"

Log "Checking the list items in the Evernote desktop application"

Connect Win7Demo //Connect to Win 7 VM

//Open Evernote desktop application and make sure Grocery List is selected

DoubleClick "EvernoteDesktopApp"

If not imagefound (30.0, "GroceryListSelected")

then

Click "GroceryList"

Click foundImageLocation()

end if

//Sync the list to update any modifications

Click "ToolsMenu"

Click "Sync"

Wait 5

Put ReadText ("CreatedTLDate","CreatedBRDate") into AppDateModified

Log "This List was Created on: " & AppDateModified

//Find the Date Created and Log it

Put ReadText ("CreatedTLDate","CreatedBRDate") into AppDateCreated

Log "This List was Created on: " & AppDateCreated

//Find the Date Last Modified and Log it

Put ReadText ("ModifiedTLDate","ModifiedBRDate") into AppDateModified

Log "This List was Last Modified on: " & AppDateModified

//Read the Contents of Grocery List

Put ReadText ("TLList","BRList") into AppListContents

Log "The list contained: " & AppListContents

//Check to see if Fruit was properly synced

If AppListContents contains Fruit

then

log "The list contained " & Fruit

else

logWarning "The item " & Fruit & " was not displayed"

end if

//Check to see if Veggie was properly synced

If AppListContents contains Veggie

then

log "The list contained " & Veggie

else

logWarning "The item " & Veggie & " was not displayed"

end if

//Close out of Browser

Click "CloseButton"

//This script accesses Evernote via Android and clears the contents

Params Fruit, Veggie //Declares parameters

Log "Clearing the list on the Android device"

Connect GalaxyS3 //Connect to the device

//Navigate to the Evernote app

Tap "AppMenu"

Tap "EverNote"

//Navigate to the list and go into edit mode

Tap "NoteIcon"

Tap "GroceryList"

Tap "EditIcon"

WaitFor 30.0, "Check"

//Delete Item 1

TypeText ShiftKey, DownArrow

Click "DeleteButton"

//Delete Item 2

TypeText ShiftKey, DownArrow

Click "DeleteButton"

//Save the list and navigate back to the home page

Tap "Check"

Wait 1

Tap "ElephantIcon"

TypeText HomeKey

WaitFor 30.0, "ChromeIcon"

set TestList to ("Test1", "Test2", "Test3") // Creates a series of script executions.

RunWithNewResults "InitialTest"

set Outcome to the result

if the status of Outcome is not "Success" then

// If the result of "InitialTest" is not "Success", gets the date and time of the run...

convert Outcome's runDate to date and long time

sendMail (to: "administrator@yourcompany.com", from: "JoeTester@yourcompany.com", subject: "Initial Test Failed", body: "Test run at" && rundate of Outcome && "had" && errors of Outcome && "errors")

// Sends email to report the date and errors of the execution. (&& joins text strings with a space between them.)

else

// Otherwise...

repeat with each testScript of TestList

// For every script in TestList,

RunWithNewResults testScript // Runs the script, then...

set Outcome to the result // puts the results into Outcome

put testScript & ":" && status of Outcome && Return after currentReport

// Adds "Script: Status", then a return character to currentReport

if the status of Outcome is "Failure" then

// If the status property is Failure...

run "CleanupScript" // runs CleanupScript

end if

end repeat // Ends after the final test in TestList

Log "Final Results" // Logs "Final Results"

repeat with each line of currentReport

log it // Logs each line in currentReport

end repeat

end if